VBS/WSH/JS - Копирует не все файлы из папки

[igorromin@vk]

Здравствуйте, суть кода в резервном копировании данных браузера. Копирует, но не все файлы из папки User Data



PHP код:

Код: Выделить всё

Set FileSystemObject = CreateObject("scripting.filesystemobject") 

set WshShell1 = WScript.CreateObject("WScript.Shell")

Set objFSO = CreateObject("Scripting.FileSystemObject")

objFSO.CopyFolder "C:\Users\" & WshShell1.ExpandEnvironmentStrings("%USERNAME%")  & "AppDataLocalGoogleChromeUser DataDefault" , "C:Backup" 

Заранее спасибо

[Iska]

Не может он ничего копировать с приведённым выше кодом.





Код:

Код: Выделить всё

Option Explicit
Dim strSourceFolder
Dim strDestFolder
With WScript.CreateObject("Scripting.FileSystemObject")
	strSourceFolder = .BuildPath(WScript.CreateObject("Shell.Application").NameSpace("shell:Local AppData").self.Path, "Google\Chrome\User Data\Default")
	strDestFolder   = "C:\Backup"
	If .FolderExists(strSourceFolder) Then
		If Not .FolderExists(strDestFolder) Then
			.CreateFolder strDestFolder
		End If
		.CopyFolder strSourceFolder, strDestFolder, True
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
	End If
End With
WScript.Quit 0

Цитата igorromin@vk:



но не все файлы из папки User Data

VBS/WSH/JS - Копирует не все файлы из папки

Закройте браузер.

[igorromin@vk]

Спасибо огромное

[igorromin@vk]

А можно что бы он не копировал подпапки, а то как выяснилось они на фиг не нужны?

[igorromin@vk]

Цитата igorromin@vk:



А можно что бы он не копировал подпапки

VBS/WSH/JS - Копирует не все файлы из папки

Нельзя. Надо менять метод копирования с «.CopyFolder()» на «.CopyFile()»:



Код:

Код: Выделить всё

Option Explicit
Dim strSourceFolder
Dim strDestFolder
With WScript.CreateObject("Scripting.FileSystemObject")
	strSourceFolder = .BuildPath(WScript.CreateObject("Shell.Application").NameSpace("shell:Local AppData").self.Path, "Google\Chrome\User Data\Default")
	strDestFolder   = "C:\Backup"
	If .FolderExists(strSourceFolder) Then
		If Not .FolderExists(strDestFolder) Then
			.CreateFolder strDestFolder
		End If
		.CopyFile .BuildPath(strSourceFolder, "*.*"), strDestFolder, True
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
	End If
End With
WScript.Quit 0