VBS/WSH/JS - Создание пользователя AD

[garbals]

Поможет кто со скриптом

нужно создать пользователя

выбрать группу в которую входит

создать его папку фамилия имя на сервере

[amel27]

где-то так (VBS):



Код:

Код: Выделить всё

strLoginName = "IvanBB"
strFirstName = "Иван"
strLastName  = "Иванов"
strRDName    = strLastName & " " & strFirstName  ' Имя объекта в AD
strPassword  = "Password#14576"
strUserOU    = "ou=OU1"
strGroup     = "cn=Group1,ou=groups"
strHomeRoot  = "\\SERVER\HOME"
Set objRoot = GetObject("LDAP://RootDSE")
Set objADSystemInfo = CreateObject("ADSystemInfo")
Set objFSO = CreateObject("Scripting.FileSystemObject")
strDomainDNSName = objADSystemInfo.DomainDNSName
strDomainDN = objRoot.Get("DefaultNamingContext")
strContainerDN = strUserOU & "," & strDomainDN
strGroupDN = strGroup & "," & strDomainDN
strUserDN = "cn=" & strLoginName & "," & strContainerDN
strHomeDirPath = strHomeRoot & "\" & strLastName & " " & strFirstName
Set objContainer = GetObject("LDAP://" & strContainerDN)
Set objUser = objContainer.Create("user","cn=" & strLoginName)
Set objGroup = GetObject("LDAP://" & strGroupDN)
objUser.Put "sAMAccountName", strLoginName
objUser.Put "userPrincipalName", strLoginName & "@" & strDomainDNSName
objUser.Put "givenName", strFirstName
objUser.Put "sn", strLastName
objUser.Put "displayName", strLastName & " " & strFirstName
objUser.Put "HomeDirectory", strHomeDirPath
objUser.Setinfo
objUser.SetPassword strPassword
objUser.AccountDisabled = FALSE
objUser.Setinfo
objGroup.Add("LDAP://" & strUserDN)
objGroup.Setinfo
objContainer.MoveHere "LDAP://" & strUserDN, "cn=" & strRDName
objContainer.Setinfo
If Not objFSO.FolderExists(strHomeDirPath) Then objFSO.CreateFolder(strHomeDirPath)

[garbals]

спасибо попробую

[ГрМакс]

Принципиально vbs? из bat проще.

[garbals]

принципиально вообще

просто хочется такую програмулину

запустил написал имя фамилию должность мыло (если нет то чтоб создалось )указал в какой группах состаит поставил птичку создать личную папку на сетвере

[amel27]

я бы папку создавал логон-скриптом от самого пользователя - права автоматически настраиваются

[amel27]

А вот действительно, какая функция будет для VBS, чтобы при добавлении пользователя в АД появлялся выбор подразделения в GUI ?

[cmdshka]

cmdshka, непосредственно в самом WSH нет средств для этого. Мазохисты могут попробовать реализовать сие посредством формирования документа html в объекте «InternetExplorer.Applcation». Нормальные выберут PowerShell и создание на нём формы.