CMD/BAT - [решено] вывод строки из *.xml

[LAKERS824]

Добрый день!



Есть папка, в которую закачиваются файлы с ftp несколько раз в день.

Названия файлов типа:3143719278_1605201290029.xml



Необходимо прочитать все файлы в папке, и вывести из каждого файла то, что содержится в строке



94595 , т.е. в этом случае вывести 94595.



Причем итоговое значение д.б. таким : первая часть имени файла остается той же, т.е. 3143719278, а через _ добавляем 94595.



Получаем на выходе: 3143719278_94595



Если же поле InsuranceNumber пустое, то вывести 3143719278_0.







Каким образом это можно сделать или вообще можно?

[Guest]

Для работы скрипта нужен

Grep

из набора утилит GNU coreutils, портированный под Windows, плюс его зависимости. Рядом со скриптом создать директорию bin, куда и сложить бинарник грепа и либы, нужные для его работы.



Код:

Код: Выделить всё

@Echo Off
SetLocal EnableDelayedExpansion
Set Path=%Path%;%CD%\bin
Set XMLPath=D:\Temp\xmlfiles
For /F "delims=" %%F In ('Dir "%XMLPath%\*.xml" /B 2^>nul') Do (
	Set Prefix=&Set InsuranceNumber=0
	For /F "delims=_" %%P In ("%%~F") Do (Set Prefix=%%P)
	For /F "tokens=2 delims=><" %%N In ('grep -Eo "<InsuranceNumber>[^<]*</InsuranceNumber>" "%XMLPath%\%%F"') Do (
		If Not %%N==/InsuranceNumber Set InsuranceNumber=%%N
	)
	Echo !Prefix!_!InsuranceNumber!
)
Pause

Скрипт вместе с обвязкой (греп+зависимости) -

http://rghost.ru/38920583

Исправил скрипт, вначале невнимательно прочел условие и не сделал обработку пустого значения.

[Guest]

Anonymоus, спасибо, заработало, НО:



Если поле InsuranceNumber содержит русские буквы, то получаем в итоге крякозябры, можно ли их исправить?

[LAKERS824]

LAKERS824, об этом в вашем условии ни слова не было, предполагалось, что InsurcanceNumber состоит из цифр, судя по примеру. Смотрите, в какой кодировке ваши XML, и в какой кодировке сохранён скрипт. Он выводит только то, что получает из файла. Пусть даже в консоли выводятся кракозябры, если перенаправить их в файл - получится читаемый текст в той самой кодировке, в которой были XML-файлы.

[LAKERS824]

Anonymоus, спасибо, заработало, НО:



Если поле InsuranceNumber содержит русские буквы, то получаем в итоге крякозябры, можно ли их исправить?

[LAKERS824]

LAKERS824, об этом в вашем условии ни слова не было, предполагалось, что InsurcanceNumber состоит из цифр, судя по примеру. Смотрите, в какой кодировке ваши XML, и в какой кодировке сохранён скрипт. Он выводит только то, что получает из файла. Пусть даже в консоли выводятся кракозябры, если перенаправить их в файл - получится читаемый текст в той самой кодировке, в которой были XML-файлы.

[LAKERS824]

LAKERS824, перенаправляется в файл - вот так:



Код:

Код: Выделить всё

Echo !Prefix!_!InsuranceNumber!>>"file.txt"

Вариант с выводом в два файла, в зависимости от длины строки после "_" :





Код:

Код: Выделить всё

@Echo Off
SetLocal EnableDelayedExpansion
Set Path=%Path%;%CD%\bin
Set XMLPath=D:\Temp\xmlfiles
For /F "delims=" %%F In ('Dir "%XMLPath%\*.xml" /B 2^>nul') Do (
	Set Prefix=&Set InsuranceNumber=0
	For /F "tokens=1,2 delims=_." %%P In ("%%~F") Do (Set Prefix=%%P&Set Suffix=%%Q)
	For /F "tokens=2 delims=><" %%N In ('grep -Eo "<InsuranceNumber>[^<]*</InsuranceNumber>" "%XMLPath%\%%F"') Do (
		If Not %%N==/InsuranceNumber Set InsuranceNumber=%%N
	)
	Call :StringLen "!Suffix!"
	If !$StringLen!==5 (Echo !Prefix!_!InsuranceNumber!>>"result5and6.txt")
	If !$StringLen!==6 (Echo !Prefix!_!InsuranceNumber!>>"result5and6.txt")
	If Not !$StringLen!==5 (
		If Not !$StringLen!==6 (
			Echo !Prefix!_!InsuranceNumber!>>"result_other.txt"
		)
	)
)
Pause&Exit
:StringLen
:: Автор функции - amel27, viewtopic.php?p=68849#p68849
   Set $StringLen=0&Set $StringBuf=%~1
   If ""=="%~1" GoTo :EOF
:StringLenLoop
   Set /A $StringLen+=1
   Call Set $StringChr=%%$StringBuf:~%$StringLen%%%
   If ""=="%$StringChr%" GOTO :EOF
GoTo :StringLenLoop

Точки в части после "_" быть не должно.

[LAKERS824]

Anonymоus, Еще такой момент, после знака _ м.б. различное кол-во символов (точка, 0, начинается с буквы, оканчивается буквой, более 5 символов, 5 символов.).



Так вот, можно ли сделать так, чтобы там где '_98765' (5 символов после _) или '_987654' (6 символов после _) - записывались в один файл, а все остальное переправлять в другой файл?

[Guest]

Точки не должно быть, потому что она используется как разделитель в delims, чтобы отделить и отбросить ненужное расширение файла.

Работает полностью, я протестировал вот на этом наборе файлов -

http://rghost.ru/39065474

[LAKERS824]

3 вопросика:



1 Почему не должно быть точки? Если она все же есть, то в какой из файлов она уйдет? в result_other.txt?

2 Работает наполовину, файла result5and6.txt так и не создается - не нашел после выполнения команды данного файла.

3 И так где 5 знаков тоже вываливаются в result_other.txt