CMD/BAT - Определение ОС

[Fresh96]

Всем - Здравствуйте.

Подскажите батничек с таким функционалом:

Есть исполняемые файлы EXE1.exe и EXE2.exe

При запуске cmd/bat должна определиться какая ОС (и какой битности) установлена на ПК

если WinXP x86 то

должен запуститься файл EXE1.exe -ключ1

если WinXP x64 то

должен запуститься файл EXE1.exe -ключ2

если Win7 x86 то

должен запуститься файл EXE2.exe -ключ1

если Win7 x64 то

должен запуститься файл EXE2.exe -ключ2



Заранее спасибо.

[gora]

Код:

Код: Выделить всё

@Echo Off
Set w7=0
Ver | Find "6.1" >Nul && Set w7=1
Set xOS=x86
If Defined PROCESSOR_ARCHITEW6432 (Set xOS=x64) Else If "%PROCESSOR_ARCHITECTURE%"=="AMD64" Set xOS=x64
If %w7%==1 (
Rem это Win7
	If %xOS%==x86 (
		Echo EXE2.exe -ключ1
	) Else (
		Echo EXE2.exe -ключ2
	)
) Else (
Rem это не Win7
	If %xOS%==x86 (
		Echo EXE1.exe -ключ1
	) Else (
		Echo EXE1.exe -ключ2
	)
)
:: Второй вариант
@Echo Off
Set w7=1
Ver | Find "6.1" >Nul && Set w7=2
Set xOS=-ключ1
If Defined PROCESSOR_ARCHITEW6432 (Set xOS=-ключ2) Else If "%PROCESSOR_ARCHITECTURE%"=="AMD64" Set xOS=-ключ2
Echo EXE%w7%.exe %xOS%
Pause>Nul

Echo добавлены для проверки, удалить перед использованием.