Любой язык - [решено] автоматизировать изменения изображения

[budanila]

Подскажите как лучше сделать следующее.

Автоматически изменить размер(разрешение) изображения. Я хочу это реализовать используя батник где вызывается прога с параметрами(входящий файл, конечное разрешение и пр.) Я остановился на том что не могу найти программу для конвертации изображений поддерживающую нужные мне параметы. Есть ли способы проще или кто-нибудь может подсказать какой программой воспользоваться....

[gora]

Писал давно, но может подойдет для Ваших целей. Удалите что не нужно...
Цитата:




Цитата:



Когда одна картинка согласен не проблема, а когда их больше десятка!!?



Скрипт для изготовления превьюшек с помощью бесплатной программы

IrfanView

. После запуска в папке со скриншотами добавятся превьюшки всех скриншотов и файл links.txt с готовым списком для вставки в пост. Нужные пути пропишите в скрипте (есть комментарии).

Код:

Код: Выделить всё

@Echo Off
Setlocal enabledelayedexpansion
Rem Путь к папке со скриншотами
Set "input_dir=c:\musor\input"
Rem Размер превьюшек
Set "maxsize=200,200"
Rem Число превьюшек в ряду
Set nummax=4
Rem Путь к папке со скриншотами на FTP (слеши прямые)
Set "ftp=http://tools.oszone.net/gora/pict"
Rem Путь к папке с программой IrfanView
Set "Irfan=%ProgramFiles%\IrfanView\i_view32.exe"
If Exist "%input_dir%\links.txt" Del /f /q "%input_dir%\links.txt"
For /R "%input_dir%" %%i In (*) Do (
	Set tmp_name=%%~ni
	If Not "!tmp_name:~-3!"=="_rz" If Not %%~xi==.txt (
		"%Irfan%" "%%i" /resize=^(%maxsize%^) /resample /aspectratio /convert="%input_dir%\%%~ni_rz%%~xi"
		Set "urls=!urls![url=%ftp%/%%~nxi][img]%ftp%/%%~ni_rz%%~xi[/img][/url]"
		Set /a num+=1
		If !num! GEQ %nummax% (
			Echo !urls!>>"%input_dir%\links.txt"
			Set num=0
			Set urls=
		)
	)
)
If Not !num!==0 Echo !urls!>>"%input_dir%\links.txt"
Exit

[budanila]

вопрос снят, нашел параметры командной строки)))



gora, Спасибо большое)))

[budanila]

[Кнопка для Total Commander]

resize selected images