VBS/WSH/JS - [решено] Скрипт vbs для создания ярлыка на рабочем столе

[angel_lyucifer]

Всем привет!

Я нашёл у вас на форуме нужный мне скрипт для создания ярлыков.

Но он у меня не работает и выдаёт ошибку, я не просто не понимаю что тут не так? Уважаемые знатоки, посмотрите его и если можете исправте пожалуйста?



PHP код:

Код: Выделить всё

@set @x=0 /*

@cscript/nologo /e:jscript "%~f0" "%~dp0file.exe" "%~dp0"

@exit */

sh=WScript.CreateObject("WScript.Shell")

lk=sh.CreateShortcut(sh.SpecialFolders("Desktop")+"\\file.lnk")

lk.TargetPath=WScript.Arguments(0)

lk.WorkingDirectory = WScript.Arguments(1)

lk.Save() 

[Iska]

angel_lyucifer, потому что это пакетный файл — гибрид из пакетного файла, вызова JScript-интерпретатора и VBScript-кода.



Сохраняете его как «Name.cmd» и вызываете, например:



Код:

Код: Выделить всё

E:\Песочница\0336\0005.cmd

В результате получаете на Рабочем столе ярлык «file.lnk», указывающий на «file.exe», находящийся рядом[/i] с пакетным файлом — т.е.: «E:\Песочница\0336\file.exe».



Одним словом, крайне неудачный выбор.

[deminand]

Цитата Iska:



Одним словом, крайне неудачный выбор.

VBS/WSH/JS - [решено] Скрипт vbs для создания ярлыка на рабочем столе

Проблема такая, у меня есть файл Vlp.exe у него может быть любая директория, но мне нужно создать ярлык скриптом, этот скрипт будет лежать рядом с файлом...

[venom05]

Цитата angel_lyucifer:



Iska

VBS/WSH/JS - [решено] Скрипт vbs для создания ярлыка на рабочем столе

Всё понял, спасибо...

[venom05]

Цитата angel_lyucifer:



у меня есть файл Vlp.exe у него может быть любая директория, но мне нужно создать ярлык скриптом, этот скрипт будет лежать рядом с файлом...

VBS/WSH/JS - [решено] Скрипт vbs для создания ярлыка на рабочем столе

Так:

читать дальше »

Код:

Код: Выделить всё

Option Explicit
Dim strFileName
Dim objFSO
Dim strPath2File
Dim objFile
strFileName = "Vlp.exe"
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
strPath2File = objFSO.BuildPath(objFSO.GetParentFolderName(WScript.ScriptFullName), strFileName)
If objFSO.FileExists(strPath2File) Then
	Set objFile = objFSO.GetFile(strPath2File)
	With WScript.CreateObject("WScript.Shell")
		With .CreateShortcut(objFSO.BuildPath(.SpecialFolders.Item("Desktop"), objFSO.GetBaseName(strFileName) & ".lnk"))
			.TargetPath       = objFile.Path
			.WorkingDirectory = objFile.ParentFolder.Path
			.Save
		End With
	End With
	Set objFile = Nothing
Else
	WScript.Echo "File [" & strPath2File & "] not found near this script."
	WScript.Quit 1
End If
Set objFSO = Nothing
WScript.Quit 0

[angel_lyucifer]

Цитата Iska:



Iska

VBS/WSH/JS - [решено] Скрипт vbs для создания ярлыка на рабочем столе

Скрипт, очень хорошей!

А как добавить описание для этого ярлыка?

[angel_lyucifer]

Код:

Код: Выделить всё

	With WScript.CreateObject("WScript.Shell")
		With .CreateShortcut(objFSO.BuildPath(.SpecialFolders.Item("Desktop"), objFSO.GetBaseName(strFileName) & ".lnk"))
			.TargetPath       = objFile.Path
			.WorkingDirectory = objFile.ParentFolder.Path
			.Description      = "Это мой ярлык"
			.Save
		End With
	End With

[Iska]

Большое спасибо, Iska!

[angel_lyucifer]

а как выполнить его на удаленном компьютере для определенного пользователя. ПК в домене.

[Iska]

Цитата deminand:



а как выполнить его на удаленном компьютере для определенного пользователя. ПК в домене.

VBS/WSH/JS - [решено] Скрипт vbs для создания ярлыка на рабочем столе

В составе LOGON-скрипта, например.