CMD/BAT - [решено] Подстановка значения в цикле FOR

[tr011_tmn]

доброго времени суток коллеги.



Прошу помощи в одном моменте, пытаюсь реализовать следующую конструкцию



Код:

Код: Выделить всё

set D=%date:~0,2%
SET M=%date:~3,2%
set /a Ma=1%M% - 101
IF %Ma% LSS 10 (SET Mm=0%Ma%) ELSE (SET Mm=%Ma%)
SET Y=%date:~6%
::
FOR /L %%B in (1,1,31) DO (
	IF NOT EXIST "%Srv%\backup" (MD "%Srv%\backup" 1>Nul 2>&1)
	IF %%B LSS 10 (SET Db=0%%B) ELSE (SET Db=%%B)
	SET bName=backup_%Y%.%M%.%Db%.7z
	SET bNameR=backup_FED_%Y%.%M%.%Db%.WRK.7z
pause
	Call :_ChkRzm
	REN "%Srv%\backup\%bName%" "%bNameR%" 1>Nul 2>&1
	FORFILES /P "%Srv%\backup" /M *.* /S /D -31 /C "CMD /c DEL /q @PATH"
)
:: 
:: ===================================================================================================== :: 
::
:_ChkRzm
::
SET Size=100
::
FOR /F %%a in ('dir /b /s /a-d "%Srv%\backup\%dName%"') do (SET x=%%~za)
::
IF %x% LEQ %Size% (DEL /S /Q "%Srv%\backup\%dName%" 1>Nul 2>&1)
::
GoTo :EOF
:: 
:: ===================================================================================================== :: 
::

не могу добиться что бы значение IF %%B LSS 10 (SET Db=0%%B) ELSE (SET Db=%%B) передавалось в SET bName=backup_%Y%.%M%.%Db%.7z.

Причем если включить отображение на экран происходящего то я вижу в строке IF %%B LSS 10 (SET Db=0%%B) ELSE (SET Db=%%B) правильные значения.



Подскажите что делаю не так.

[Foreigner]

Одни и те же грабли, каждый божий день. Либо выносите блок кода из-за скобок, либо применяйте инструкцию:



Код:

Код: Выделить всё

setlocal enabledelayedexpansion

Код:

Код: Выделить всё

@echo off
setlocal enabledelayedexpansion
....
FOR /L %%B in (1,1,31) DO (
	IF NOT EXIST "%Srv%\backup" (MD "%Srv%\backup" 1>Nul 2>&1)
	IF %%B LSS 10 (SET Db=0%%B) ELSE (SET Db=%%B)
	SET bName=backup_%Y%.%M%.!Db!.7z
	SET bNameR=backup_FED_%Y%.%M%.!Db!.WRK.7z
pause
	Call :_ChkRzm
	REN "%Srv%\backup\!bName!" "!bNameR!" 1>Nul 2>&1
	FORFILES /P "%Srv%\backup" /M *.* /S /D -31 /C "CMD /c DEL /q @PATH"
)
.....

[tr011_tmn]

Цитата Foreigner:



Либо выносите блок кода из-за скобок

CMD/BAT - [решено] Подстановка значения в цикле FOR

подскажите какой код блока, ибо



использовал (просто забыл указать что использую):SetLocal EnableDelayedExpansion



и при замене % на ! получаю теперь на выходе стрку типа:



Код:

Код: Выделить всё

IF 1 LSS 10 (SET Db=01 ) ELSE (SET Db=1 )
SET bName=backup_2016.04.!Db!.7z
SET bNameR=backup_FED_2016.04.!Db!.WRK.7z
pause

[Foreigner]

Приблизительно так (не проверял, просто вынес тело цикла наружу)



Код:

Код: Выделить всё

@echo off
setlocal
set D=%date:~0,2%
set M=%date:~3,2%
set /a Ma=1%M% - 101
IF %Ma% LSS 10 (SET Mm=0%Ma%) ELSE (SET Mm=%Ma%)
set Y=%date:~6%
FOR /L %%B in (1,1,31) DO call:0 %%B
goto:eof
:0
IF NOT EXIST "%Srv%\backup" (MD "%Srv%\backup" 1>Nul 2>&1)
IF %1 LSS 10 (SET Db=0%1) ELSE (SET Db=%1)
SET bName=backup_%Y%.%M%.%Db%.7z
SET bNameR=backup_FED_%Y%.%M%.%Db%.WRK.7z
pause
SET Size=100
FOR /F %%a in ('dir /b /s /a-d "%Srv%\backup\%dName%"') do (SET x=%%~za)
IF %x% LEQ %Size% (DEL /S /Q "%Srv%\backup\%dName%" 1>Nul 2>&1)
REN "%Srv%\backup\%bName%" "%bNameR%" 1>Nul 2>&1
FORFILES /P "%Srv%\backup" /M *.* /S /D -31 /C "CMD /c DEL /q @PATH"

[tr011_tmn]

Цитата Foreigner:



Приблизительно так (не проверял, просто вынес тело цикла наружу)

CMD/BAT - [решено] Подстановка значения в цикле FOR

пасибо большое, все заработало. даже превзошло все ожидания.