Любой язык - [решено] Применение твиков реестра ко всем учетным записям после установки ОС Windows 7

[SANIOK_AV]

Доброго времени суток!

Раньше в ХР для применения твиков реестра ко всем учетным записям после установки ОС пользовался батником:



Код:

Код: Выделить всё

@echo off
:: Извлекаем из реестра полный путь к папке, содержащей профили пользователей
for /f "usebackq tokens=3,3* delims==	" %%i in (`reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /v ProfilesDirectory`) do set profiles=%%i
:: Полученный путь используем в качестве новой переменной %profiles%
for /f "usebackq delims==" %%i in (`echo %profiles%`) do set profiles=%%i
:: Для всех профилей пользователей (кроме All Users и %Username%) поочередно загружаем пользовательский
 :: куст реестра, представляющий собой файл NTUSER.DAT и импортируем в него заранее подготовленный
 :: REG-файл, содержащий твики реестра.
For /F "usebackq tokens=* delims==" %%i in (`DIR /B /AD-S "%profiles%" ^| FINDSTR /V /B /I /C:"All Users" /C:"%username%"`) DO (
   reg load HKEY_USERS\Custom "%profiles%\%%i\NTUSER.DAT"
   reg import tweak.reg
   reg unload HKEY_USERS\Custom
)
exit

из

статьи

Но вот в Windows 7 он у меня не захотел работать

Подскажите пожалуйста как в Windows 7 можно реализовать применение твиков реестра ко всем учетным записям.

Заранее благодарен!!!

[SANIOK_AV]

Делал поиск по своим темам и наткнулся на эту...

Как оказывается, ларчик открывался просто :

В строке

Код:

Код: Выделить всё

:: Извлекаем из реестра полный путь к папке, содержащей профили пользователей
for /f "usebackq tokens=3,3* delims==	" %%i in (`reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList" /v ProfilesDirectory`) do set profiles=%%i

после "delims==" нужно было всего лишь навсего символ табуляции поменять на пробел



Ну и (не обязательно, но во избежанеие вывода лишних ошибок на экран) в строке

Код:

Код: Выделить всё

For /F "usebackq tokens=* delims==" %%i in (`DIR /B /AD-S "%profiles%" ^| FINDSTR /V /B /I /C:"All Users" /C:"%username%"`) DO (

ключ /C:"All Users" поменять на /C:"Public"