2013 - [решено] Не проходит проверка текста на плагиат

[Игорь сергеевич]

Здравствуйте уважаемые программисты! Начну с того, что студент принес мне файл word. В данном файле имеется текст (ВЫСО‏ЧАЙШЕ‏Е‏ УТВЕ‏РЖДЁННО‏Е‏ О‏БЩЕ‏Е‏ ПО‏ЛО‏ЖЕ‏НИЕ‏ О‏ КРЕ‏СТЬЯНАХ, ВЫШЕ‏ДШИХ ИЗ КРЕ‏ПО‏СТНО‏Й ЗАВИСИМО‏СТИ 1861 ГО‏Д (ВЫДЕ‏РЖКИ)). Проверив этот текст на плагиат, его уникальность состовляла 3%. После чего работа студенту была возвращена. На следующий день студент мне снова принес этот докуммент, и проверив его уникальность, работа составляла уже 97% уникальности. Сравнив оба документа текст оказался идентичным. В сети прочитал огромное количество статей. Но не смог понять как он это сделал. Заметил

лишь одно, скопированный текст из word, вставленный в обычный блокнот, превращается в вопросительные знаки. Подскажите, как такое может быть?



PS. - В word текст ни чем не примечателен. (обычный текст). Но когда я его копирую, вставляю в блокнот, и сохраняю в блокноте, при этом использую кодировку не юникод, а ANSI, получается текст вот такого содержания (для примера прикрепил файл).-



Субъе?кто?м со?бстве?нно?сти в бо?льшинстве? ре?гио?но?в стано?вилась о?бщина, в не?ко?то?рых райо?нах - кре?стьянский дво?р.

[Coutty]

Вставлен непечатаемый символ из Юникода. Какой конкретно - затрудняюсь сказать. Что-то вроде пробела нулевой длины (там какие-то три байта получаются: E2 80 8F, если вас интересуют такие подробности)

Быть может, использовалась какая-нибудь система "анти-антиплагиат", которая сама вставляет эти спецсимволы. Но суть одна и та же.

[Iska]

Это один символ:

Unicode Character 'RIGHT-TO-LEFT MARK' (U+200F)

.



Убрать можно примерно так (пока что-нибудь другое не начнут вставлять):



Код:

Код: Выделить всё

Option Explicit
Sub DeleteChars()
    Dim char As Range
    For Each char In ActiveDocument.Content.Characters
        If AscW(char.Text) = 8207 Then
            char.Delete
        End If
    Next
End Sub

[Coutty]

Ну или вставить в тот же блокнот, скопировать знак вопроса и через "поиск и замену" их потереть.

[Iska]

Цитата Coutty:



Ну или вставить в тот же блокнот, скопировать знак вопроса и через "поиск и замену" их потереть.

2013 - [решено] Не проходит проверка текста на плагиат

Угу. Ещё проще и быстрее.

[Игорь сергеевич]

Друзья благодарю вас! Мои студенты будут вам "благодарны". Если можно еще такой вопрос.



В worde изменяют цвет шрифта, (черный в белый). Подскажите как написать макрос, что бы автоматически весь белый цвет()который был специально изменен), превратить в красный цвет. Если поможите, буду самым счастливым человеком.

[Sham]

Там автозапись макроса есть. Жмите "начать запись", и дальше поиск/замена по формату (шрифт - цвет шрифта, для полей поиск и замена свой цвет).

[Sham]

Из письма в ПМ:


Цитата Игорь сергеевич:



Если можно еще такой вопрос.



В worde изменяют цвет шрифта, (черный в белый). Подскажите как написать макрос, что бы автоматически весь белый цвет()который был специально изменен), превратить в красный цвет.



Вот две процедуры:

читать дальше »

Код:

Код: Выделить всё

Option Explicit
Sub FindWhiteFontAndToRed()
    With ActiveDocument.Content.Find
        .ClearFormatting
        .Text = ""
        .Font.ColorIndex = wdWhite
        With .Replacement
            .ClearFormatting
            .Text = ""
            .Font.ColorIndex = wdRed
        End With
        .Format = True
        .Forward = True
        .Wrap = wdFindContinue
        .Execute Replace:=wdReplaceAll
    End With
End Sub
Sub FindWhiteFontAndHighlight()
    Options.DefaultHighlightColorIndex = wdRed
    With ActiveDocument.Content.Find
        .ClearFormatting
        .Text = ""
        .Font.ColorIndex = wdWhite
        With .Replacement
            .ClearFormatting
            .Text = ""
            .Highlight = True
        End With
        .Format = True
        .Forward = True
        .Wrap = wdFindContinue
        .Execute Replace:=wdReplaceAll
    End With
    Options.DefaultHighlightColorIndex = wdAuto
End Sub

Первая процедура, как и заказывали, ищет текст со шрифтом белого цвета и меняет его на красный. Вторая — так же ищет текст со шрифтом белого цвета и подсвечивает его.

читать дальше »

P.S. Вам нужно почистить переполненную личку от сообщений — я не смог отправить Вам ответ.

[Игорь сергеевич]

Iska, Очень вам признателен.